Private Sub createPdfButton_Click(ByVal sender As Object, ByVal e As EventArgs) Handles createPdfButton.Click
    ' Create a PDF document
    Dim pdfDocument As New Document()

    ' Set license key received after purchase to use the converter in licensed mode
    ' Leave it not set to use the converter in demo mode
    pdfDocument.LicenseKey = "fvDh8eDx4fHg4P/h8eLg/+Dj/+jo6Og="

    ' Add a PDF page to PDF document
    Dim pdfPage As PdfPage = pdfDocument.AddPage()

    Cursor = Cursors.WaitCursor

    Dim outPdfFile As String = "DemoAppFiles\Output\PDF_Creator\Change_Header_Footer_Per_Page.pdf"
    Dim htmlToPdfElement As HtmlToPdfElement = Nothing
    Try
        ' Add a default document header
        AddHeader(pdfDocument, True)

        ' Add a default document footer
        AddFooter(pdfDocument, True, True)

        ' Create a HTML to PDF element to add to document
        htmlToPdfElement = New HtmlToPdfElement(0, 0, urlTextBox.Text)

        ' Optionally set a delay before conversion to allow asynchonous scripts to finish
        htmlToPdfElement.ConversionDelay = 2

        ' Install a handler where to change the header and footer in pages generated by the HTML to PDF element
        AddHandler htmlToPdfElement.PrepareRenderPdfPageEvent, AddressOf htmlToPdfElement_PrepareRenderPdfPageEvent

        ' Add the HTML to PDF element to document
        ' This will raise the PrepareRenderPdfPageEvent event where the header can be changed per page
        pdfPage.AddElement(htmlToPdfElement)

        ' Save the PDF document in a memory buffer
        Dim outPdfBuffer() As Byte = pdfDocument.Save()

        ' Write the memory buffer in a PDF file
        System.IO.File.WriteAllBytes(outPdfFile, outPdfBuffer)
    Catch ex As Exception
        ' The PDF creation failed
        MessageBox.Show(String.Format("Create PDF Document Error. {0}", ex.Message))
        Return
    Finally
        ' uninstall handler
        RemoveHandler htmlToPdfElement.PrepareRenderPdfPageEvent, AddressOf htmlToPdfElement_PrepareRenderPdfPageEvent

        ' Close the PDF document
        pdfDocument.Close()

        Cursor = Cursors.Arrow
    End Try

    ' Open the created PDF document in default PDF viewer
    Try
        Process.Start(outPdfFile)
    Catch ex As Exception
        MessageBox.Show(String.Format("Cannot open created PDF file '{0}'. {1}", outPdfFile, ex.Message))
    End Try
End Sub

''' <summary>
''' The handler for HtmlToPdfElement.PrepareRenderPdfPageEvent event where you can set the visibility of header and footer
''' in each page or you can add a custom header or footer in a page
''' </summary>
''' <param name="eventParams">The event parameter containin the PDF page to customize before rendering</param>
Private Sub htmlToPdfElement_PrepareRenderPdfPageEvent(ByVal eventParams As PrepareRenderPdfPageParams)
    If (eventParams.PageNumber = 1) AndAlso changeHeaderAndFooterCheckBox.Checked Then
        ' Change the header and footer in first page with an alternative header and footer

        ' The PDF page being rendered
        Dim pdfPage As PdfPage = eventParams.Page

        ' Add a custom header of 80 points in height to this page
        ' The default document header will be replaced in this page
        pdfPage.AddHeaderTemplate(80)
        ' Draw the page header elements
        DrawAlternativePageHeader(pdfPage.Header, True)

        ' Add a custom footer of 80 points in height to this page
        ' The default document footer will be replaced in this page
        pdfPage.AddFooterTemplate(80)
        ' Draw the page header elements
        DrawAlternativePageFooter(pdfPage.Footer, True, True)
    End If
End Sub

''' <summary>
''' Add a header to document
''' </summary>
''' <param name="pdfDocument">The PDF document object</param>
''' <param name="drawHeaderLine">A flag indicating if a line should be drawn at the bottom of the header</param>
Private Sub AddHeader(ByVal pdfDocument As Document, ByVal drawHeaderLine As Boolean)
    Dim headerHtmlUrl As String = System.IO.Path.Combine(Application.StartupPath, "DemoAppFiles\Input\HTML_Files\Header_HTML.html")

    ' Create the document header template
    pdfDocument.AddHeaderTemplate(60)

    ' Create a HTML element to be added in header
    Dim headerHtml As New HtmlToPdfElement(headerHtmlUrl)

    ' Set the HTML element to fit the container height
    headerHtml.FitHeight = True

    ' Add HTML element to header
    pdfDocument.Header.AddElement(headerHtml)

    If drawHeaderLine Then
        Dim headerWidth As Single = pdfDocument.Header.Width
        Dim headerHeight As Single = pdfDocument.Header.Height

        ' Create a line element for the bottom of the header
        Dim headerLine As New LineElement(0, headerHeight - 1, headerWidth, headerHeight - 1)

        ' Set line color
        headerLine.ForeColor = Color.Gray

        ' Add line element to the bottom of the header
        pdfDocument.Header.AddElement(headerLine)
    End If
End Sub

''' <summary>
''' Add a footer to document
''' </summary>
''' <param name="pdfDocument">The PDF document object</param>
''' <param name="addPageNumbers">A flag indicating if the page numbering is present in footer</param>
''' <param name="drawFooterLine">A flag indicating if a line should be drawn at the top of the footer</param>
Private Sub AddFooter(ByVal pdfDocument As Document, ByVal addPageNumbers As Boolean, ByVal drawFooterLine As Boolean)
    Dim footerHtmlUrl As String = System.IO.Path.Combine(Application.StartupPath, "DemoAppFiles\Input\HTML_Files\Footer_HTML.html")

    ' Create the document footer template
    pdfDocument.AddFooterTemplate(60)

    ' Set footer background color
    Dim backColorRectangle As New RectangleElement(0, 0, pdfDocument.Footer.Width, pdfDocument.Footer.Height)
    backColorRectangle.BackColor = Color.WhiteSmoke
    pdfDocument.Footer.AddElement(backColorRectangle)

    ' Create a HTML element to be added in footer
    Dim footerHtml As New HtmlToPdfElement(footerHtmlUrl)

    ' Set the HTML element to fit the container height
    footerHtml.FitHeight = True

    ' Add HTML element to footer
    pdfDocument.Footer.AddElement(footerHtml)

    ' Add page numbering
    If addPageNumbers Then
        ' Create a text element with page numbering place holders &p; and & P;
        Dim footerText As New TextElement(0, 30, "Page &p; of &P;  ", New Font(New FontFamily("Times New Roman"), 10, GraphicsUnit.Point))

        ' Align the text at the right of the footer
        footerText.TextAlign = HorizontalTextAlign.Right

        ' Set page numbering text color
        footerText.ForeColor = Color.Navy

        ' Embed the text element font in PDF
        footerText.EmbedSysFont = True

        ' Add the text element to footer
        pdfDocument.Footer.AddElement(footerText)
    End If

    If drawFooterLine Then
        Dim footerWidth As Single = pdfDocument.Footer.Width

        ' Create a line element for the top of the footer
        Dim footerLine As New LineElement(0, 0, footerWidth, 0)

        ' Set line color
        footerLine.ForeColor = Color.Gray

        ' Add line element to the bottom of the footer
        pdfDocument.Footer.AddElement(footerLine)
    End If
End Sub

''' <summary>
''' Draw the alternative page header elements
''' </summary>
''' <param name="headerTemplate">The page header template</param>
''' <param name="drawHeaderLine">A flag indicating if a line should be drawn at the bottom of the header</param>
Private Sub DrawAlternativePageHeader(ByVal headerTemplate As Template, ByVal drawHeaderLine As Boolean)
    Dim headerHtmlUrl As String = System.IO.Path.Combine(Application.StartupPath, "DemoAppFiles\Input\HTML_Files\Header_Alt_HTML.html")

    ' Create a HTML element to be added in header
    Dim headerHtml As New HtmlToPdfElement(headerHtmlUrl)

    ' Set the HTML element to fit the container height
    headerHtml.FitHeight = True

    ' Add HTML element to header
    headerTemplate.AddElement(headerHtml)

    If drawHeaderLine Then
        Dim headerWidth As Single = headerTemplate.Width
        Dim headerHeight As Single = headerTemplate.Height

        ' Create a line element for the bottom of the header
        Dim headerLine As New LineElement(0, headerHeight - 1, headerWidth, headerHeight - 1)

        ' Set line color
        headerLine.ForeColor = Color.Gray

        ' Add line element to the bottom of the header
        headerTemplate.AddElement(headerLine)
    End If
End Sub

''' <summary>
''' Draw the alternative page footer elements
''' </summary>
''' <param name="htmlToPdfConverter">The HTML to PDF Converter object</param>
''' <param name="addPageNumbers">A flag indicating if the page numbering is present in footer</param>
''' <param name="drawFooterLine">A flag indicating if a line should be drawn at the top of the footer</param>
Private Sub DrawAlternativePageFooter(ByVal footerTemplate As Template, ByVal addPageNumbers As Boolean, ByVal drawFooterLine As Boolean)
    Dim footerHtmlUrl As String = System.IO.Path.Combine(Application.StartupPath, "DemoAppFiles\Input\HTML_Files\Footer_Alt_HTML.html")

    ' Create a HTML element to be added in footer
    Dim footerHtml As New HtmlToPdfElement(footerHtmlUrl)

    ' Set the HTML element to fit the container height
    footerHtml.FitHeight = True

    ' Add HTML element to footer
    footerTemplate.AddElement(footerHtml)

    ' Add page numbering
    If addPageNumbers Then
        ' Create a text element with page numbering place holders &p; and & P;
        Dim footerText As New TextElement(10, 30, "Page &p; of &P;", New Font(New FontFamily("Times New Roman"), 10, GraphicsUnit.Point))

        ' Align the text at the right of the footer
        footerText.TextAlign = HorizontalTextAlign.Left

        ' Set page numbering text color
        footerText.ForeColor = Color.Navy

        ' Embed the text element font in PDF
        footerText.EmbedSysFont = True

        ' Add the text element to footer
        footerTemplate.AddElement(footerText)
    End If

    If drawFooterLine Then
        Dim footerWidth As Single = footerTemplate.Width

        ' Create a line element for the top of the footer
        Dim footerLine As New LineElement(0, 0, footerWidth, 0)

        ' Set line color
        footerLine.ForeColor = Color.Gray

        ' Add line element to the bottom of the footer
        footerTemplate.AddElement(footerLine)
    End If
End Sub